Conditions:
(documentation) | sus := "(?x)\b(?:
#Common words
amazing
|anal
|ass+
|balls
|big[ ]black
|boobs
|booty
|bum
|butt
|caca
|cheeks
|cool(?:est)?
|creeps?
|cum
|daddy
|fart(?:ed|ing|s)?
|fat
|gay(?:est|s)?
|haha
|hehe
|hello
|hola
|(?<!\S)hi(?!\S)
|i[ ](?:like|love|hate)
|idk
|is[ ]fake
|is[ ]the[ ](?:best|worst)
|m[ou]m(?:my)?
|morons?
|nonces?
|oh[ ]no
|omg
|poo+
|porno?
|puta
|racists?
|retards?
|sexy
|scumbags?
|smell[ys]
|stink[ys]
|stupid
|suck(?:ed|ing|s)?
|tits
|toes
|(?<!\S)ur(?!\S)
|vaginas?
|yummy
#Memes
|among[ ]us
|fortnite
|ronaldo
|sigmas?
|the[ ]goat
)\b";
page_namespace == 0 &
!("confirmed" in user_groups) &
edit_delta < 1000 &
(
match := get_matches("(?i)" + sus, added_lines)[0];
match & (
escaped_match := "(?:\b" + rescape(match) + "\b)";
!(removed_lines irlike sus) &
!((old_wikitext + added_links) irlike escaped_match)
)
) & (
/* Baseline AGF */
score := 0.5;
/* More AGF on "sweary" pages (no need to include all of 384 here; just what's common in existing pages */
score := score + 0.25 * rcount("(?i)fuck|\bshit|bitch|" + sus, old_wikitext);
/* More AGF on fiction or music related pages */
score := score + 2.0 * (new_wikitext irlike "(?x)
category:.*(?:films|shows|books|series|studios|episodes|bands|musical[ ]groups|albums|songs)
|discography
|filmography
");
/* Added references */
ref_cnt := (count("<ref", added_lines) - count("<ref", removed_lines));
clamped_ref_cnt := ref_cnt < -1 ? -1 : ref_cnt;
score := score + 2.0 * clamped_ref_cnt;
/* Added markup */
markup_cnt := (rcount("[[\]{}|*#=]", added_lines)) - (rcount("[[\]{}|*#=]", removed_lines));
clamped_markup_cnt := markup_cnt < -10 ? -10 : markup_cnt;
score := score + 0.1 * clamped_markup_cnt;
/* Added quotes or italics */
quote := "(?<!')''(?!')|[\"\x{201C}\x{201D}]";
quote_cnt := (rcount(quote, added_lines)) - rcount(quote, removed_lines);
clamped_quote_cnt := quote_cnt < 0 ? 0 : quote_cnt;
score := score + 0.5 * clamped_quote_cnt;
/* Unencyclopedic language */
bonus_words := "\b(?:i|me|my|your?)\b";
score := score - 0.5 * (
added_lines irlike bonus_words &
!(removed_lines irlike bonus_words) &
!(match irlike bonus_words) /* Avoid double-counting "i like", etc. */
);
/* More points for a long summary, unless it's one of the mobile suggestions */
sum := get_matches("^(?:/\*.*?\*/)?\s*(.*)\s*$", summary)[1];
if !(sum irlike "added content|fixed typo") then (
score := score + 0.02 * length(sum);
) end;
/* Did they add these words and do nothing else except adjust whitespace and punctuation? */
score := score - 2.0 * (norm(str_replace_regexp(added_lines, sus, "")) == norm(removed_lines));
/* Multiple bad words (different from the first match; if that has one legit. use, it has many) */
extra_cnt := rcount("(?i)(?!" + escaped_match + ")" + sus, added_lines);
clamped_extra_cnt := extra_cnt > 4 ? 4 : extra_cnt;
score := score - 0.5 * clamped_extra_cnt;
/* Back-to-back bad words */
score := score - 2.5 * (added_lines irlike ("(?:(?:" + sus + ")\W*){2}"));
/* If the word count is exactly the same, that probably means they just swapped out one word, or did a search-and-replace */
score := score - 1.0 * (rcount("\w+", added_lines) == rcount("\w+", removed_lines));
/* Anything in all caps, not necessarily these words */
score := score - 1.0 * (rcount("[A-Z]{4,}", added_lines) > rcount("[A-Z]{4,}", removed_lines));
if (!quote_cnt & !ref_cnt & !markup_cnt) then (
/* Added plain text to the end of a single line */
score := score - 1.0 * (
strpos(rmwhitespace(added_lines), rmwhitespace(removed_lines)) != -1 &
length(added_lines) == 1 &
length(removed_lines) == 1
);
/* Added plain text to the start or end of the page */
score := score - 2.0 * (strpos(rmwhitespace(new_wikitext), rmwhitespace(old_wikitext)) != -1);
/* No changes at all to punctuation or markup */
score := score - 2.0 * (str_replace_regexp(added_lines, "[\w\s]", "") == str_replace_regexp(removed_lines, "[\w\s]", ""));
) end;
/* Not much use of the shift key */
score := score - 1.0 * (rcount('[A-Z]', added_lines) == rcount('[A-Z]', removed_lines));
/* Red link containing the specific word they added */
score := score - 2.0 * (new_html irlike ('class="new" title="[^"]*' + escaped_match));
/* Unbalanced markup */
score := score - 2.0 * (
rcount("[{\[]", added_lines) != rcount("[}\]]", added_lines) &
rcount("[{\[]", old_wikitext) == rcount("[}\]]", old_wikitext)
);
/* No punctuation or numbers between matched word and end of the line */
score := score - 2.0 * (
added_lines irlike ("(?m)" + escaped_match + "[a-z ]*$")
);
score < 0
)
|
| Tools: | Export this filter to another wiki
|
